누구나 내 폴더에 자료를 넣을 수 있도록, 쓰기 가능한 공유 폴더를 만들어 놓는다.
어느 경우 공유된 폴더의 내용을 옮겨야 하는 경우가 생긴다.
다른 사람에게 공유 되지 말아야 할 내용이나,
누군가 잘못 지우지 말아야 할 파일이 공유 폴더에 있을 때이다.
이럴때, 배치파일 클릭으로 새로운 공유 폴더를 생성한다.
물론 공유명은 변경되지 않는다.
배치 파일이 하는 일을 단계별로 정리하면,
(1) 기존 공유 폴더의 공유를 해제한다. (아래 예에서는 "OPEN"이라는 공유명)
(2) 새로운 폴더를 만든다. (날짜가 폴더 이름에 들어간다.)
(3) 새로 만든 폴더를 기존 공유 이름으로 공유 설정한다. (읽고 쓰기 가능)
배치파일 내용은 아래와 같다.
@echo off
net share OPEN /delete
date < nul > do.bat
echo . >> do.bat
echo mkdir OPEN_%%2 > 현재.bat
echo cd OPEN_%%2 >> 현재.bat
echo set cwd=%%cd%% >> 현재.bat
echo cd .. >> 현재.bat
echo net share OPEN=%%cwd%% >> 현재.bat
echo cacls %%cwd%% /g everyone:F >> 현재.bat
call do.bat
del do.bat
del 현재.bat
이 파일에는 세 가지 유용한 팁이 포함 되어 있다.
(1) 배치파일에서 현재 날짜를 변수로 저장하는 기술
(2) 명령행에서 폴더 공유 명령어 : net
(3) 명령행에서 폴더 권한 변경 명령어 : cacls
공유 명령만으로는 읽고 쓰기 가능한 폴더 공유가 되지 않는다.
net으로 폴더의 공유명을 지정하고, cacls로 폴더의 권한을 누구나 읽고 쓸 수 있게 변경해주어야 한다.
배치파일 설명,
공유명은 OPEN이다. 실제 폴더의 이름은 OPEN_2009-02-24 처럼 날짜가 포함된 폴더이다.
공유명을 바꾸려면 OPEN을 변경하면 되고 (두군데, net share OPEN ...의 OPEN),
폴더 이름을 바꾸려면, OPEN_ 으로 나온 부분 (다섯째, 여섯째 줄)을 변경해 주면 된다.
그래도 날짜는 포함해야 한다.
단점, 하루에 한번밖에 사용하지 못한다. 새로운 이름을 오늘 날짜로 밖에 설정할 수 없으니까...
날짜와 시간을 같이 나오게 하려 했는데, 시간에 콜론(':')이 들어 있어서 폴더 이름으로 작성할 수가 없었다.
시작에 넣어두면, 매일 새로운 공유 폴더를 자동으로 생성할 수도 있다.
물론 보는 쪽에서는 동일한 공유 폴더명이지만. ...
사용법은 자료를 넣고 받는 폴더를 만들고, 그안에 배치 파일을 넣어 놓고,
클릭해서 실행한다. 그럼 폴더가 생성되고, 그 폴더가 공유 될 것이다.
폴더가 가득차거나 하면(공유 폴더에 너무 파일이 많아지면),
배치 파일을 다시 한번 클릭해 준다.
이전 폴더는 공유가 해제되고, 새로운 폴더로 동일한 공유명으로 폴더 공유가 시작된다.
누군가에게 유용할까? 음...
추가!
Revision 2
1. 공유권한 설정시 y를 눌러 주어야 하는 불편함 해소
2. 띄어쓰기가 있는 폴더의 경우도 정상적으로 공유 가능
사용법
공유명과 폴더명을 자신이 원하는 것으로 바꾸고, 공유폴더를 만들기 원하는
상위 폴더에서 실행시킨다. 아래 기본 공유명은 OPEN 이고, 폴더명은 "OPEN_날짜"이다.
배치파일 내용
@echo off
REM daily folder share rotating batch file
REM 매일 공유폴더 변경 배치파일
net share OPEN /delete
date < nul > do.bat
echo . >> do.bat
echo mkdir OPEN_%%2 > 현재.bat
echo cd OPEN_%%2 >> 현재.bat
echo set cwd="%%cd%%" >> 현재.bat
echo cd .. >> 현재.bat
echo net share OPEN=%%cwd%% >> 현재.bat
echo cacls %%cwd%% /g everyone:F >> 현재.bat
echo y|call do.bat
del do.bat
del 현재.bat
배치파일 설명
@echo off
REM daily folder share rotating batch file
REM 매일 공유폴더 변경 배치파일
net share OPEN /delete : 기존 공유명을 삭제
date < nul > do.bat : '현재 날짜: 2009-05-12'가 적힌 배치 do.bat 생성
echo . >> do.bat : 새로운 날짜 입력 취소를 위한 엔터 입력
echo mkdir OPEN_%%2 > 현재.bat : 두번째 명령행 인수로 폴더이름을 만드는 배치 현재.bat
echo cd OPEN_%%2 >> 현재.bat : 만들어진 폴더로 이동
echo set cwd="%%cd%%" >> 현재.bat : 현재 폴더 위치 변수 cd를 변수명 cwd로 저장
echo cd .. >> 현재.bat
echo net share OPEN=%%cwd%% >> 현재.bat : 만들어진 폴더 공유
echo cacls %%cwd%% /g everyone:F >> 현재.bat : 만들어진 폴더 권한 변경 (모두 쓰기 가능)
echo y|call do.bat : 배치파일 실행, do에서 현재.bat 실행
del do.bat : 사용후 배치 삭제
del 현재.bat : 사용후 배치 삭제
|
|
추천 : 